"Unicorn Aspirations" by "ExpressCloud Team"

Volume 1 - Bibliographical Detail

Use American dialect and the serial comma.
Use no scoring.
Use no deprecated features.
The story headline is "An Interactive Digestive".
The story genre is "Fantasy".
The release number is 1 .
The story description is "A unicorn aspires to the clouds."
The story creation year is 2013.

Release along with the source text, a public solution, cover art, a website, and an interpreter.

Volume 2 - Properties and Actions
	
Farting is an action applying to nothing.  Understand "fart", "poot", "toot", "pass gas", "break wind", and "flatulate" as farting.

Burping is an action applying to nothing.  Understand "burp", "belch", and "praise the chef" as burping.  Carry out burping: instead say "No unicorn ever reached the clouds by belching."

Digesting is an action applying to one thing.  Understand "digest [a thing]" as digesting.  Carry out digesting:
	if the noun is not held by the player, instead say "That would be quite a feat, considering you have not eaten [the noun].";
	instead say "Working on it, thanks."

Digesting intransitively is an action applying to nothing.  Understand "digest" as digesting intransitively.  Carry out digesting intransitively:
	if nothing is held by the player, instead say "Your digestive juices grind against each other, futilely.";
	instead try digesting a random thing held by the player.

Pooping is an action applying to nothing.  Understand "poop", "crap", "defecate", and "poo" as pooping.  Carry out pooping:
	if nothing is held by the player, instead say "Your digestive tract is completely empty.";
	instead try dropping a random thing held by the player.

Xyzzying is an action applying to nothing.  Understand "xyzzy" as xyzzying.  Carry out xyzzying: instead say "You hiccup, and a particolored butterfly flaps from your mouth and flies away."

Scenery_food is a kind of thing.  It is scenery.  It is edible.  Scenery_food has a thing called actual_food. Does the player mean doing something to scenery_food: it is unlikely.

Chromatic_food is a kind of thing.  It is edible.  Chromatic_food has some text called a color.  Does the player mean doing something to chromatic_food: it is likely.

Does the player mean doing something to a thing held by the player: it is very unlikely.

This is the disallow multiple objects rule:
	let L be the multiple object list;
	if the number of entries in L is greater than 1:
		say "You cannot use multiple objects with that verb.";
		stop the action.
	
The disallow multiple objects rule is listed before the generate action rule in the turn sequence rules.
		
Rule for deciding whether all includes scenery: it does not.  Rule for deciding whether all includes objects held by the player: it does not.

Before eating anything:
	if the noun is visible:
		instead try taking the noun.
		
Before tasting scenery_food:
	instead try eating the noun.
		
Instead of smelling scenery_food:
	let f be the actual_food of the noun;
	if f is an edible thing:
		if f is not held by the player:
			move f to the location;
		try smelling f;
	otherwise:
		say "You smell nothing unusual."
		
Instead of taking scenery_food:
	let f be the actual_food of the noun;
	if f is an edible thing and f is not held by the player:
		move f to the location;
		try taking f;
	otherwise:
		instead say "You can't really take [the noun]."
		
After examining scenery_food:
	let f be the actual_food of the noun;
	if f is not held by the player:
		move f to the location.

To decide what text is foodcolored ( f - a chromatic_food ) (this is foodcoloring):
	decide on the color of f.

Carry out farting:
	let adverb be "weakly";
	let fartbreezes be "wisps";
	if the player encloses the beans:
		now adverb is "forcefully";
		now fartbreezes is "jets of gas";
	If the player encloses nothing:
		instead say "You haven't got anything with which to generate even a pathetic fart.";
	let r be the list of chromatic_foods held by the player;
	if the number of entries in r is 0:
		instead say "You release a melodious but hollow D-minor fart.";
	let c be foodcoloring applied to r;
	If the number of entries in r is less than seven:
		instead say "You fart [adverb], expelling [c] [fartbreezes].";
	if the player does not enclose the beans:
		instead say "You poot out a sad little rainbow, which flutters limply to the ground in an A-minor whine before dissipating.";
	say "With a deafening C-major chord, you proudly fart a mighty rainbow blast.  Slowly at first, but swiftly gathering speed, you lift off the ground, and then zoom into the heavens, rising on a majestic rainbow rocket exhaust.";
	end the story finally saying "You have ascended to the skies".
	
Before taking an inedible thing:
	if the noun is scenery:
		instead say "[The noun] is too far away to reach.";
	otherwise:
		instead say "Lacking hands, your mouth is the only way you have to pick anything up, and [the noun] doesn't look very tasty."	
		
Understand "look up" as looking up.
Looking up is an action applying to nothing.  Carry out looking up: instead try examining the sky.

Understand "fly" as flying.  Flying is an action applying to nothing.  Carry out flying: instead try going up.
	
Before eating an edible thing: 
	if the noun is held by the player:
		say "You already ate [the noun].";
		stop the action;
	otherwise:
		instead try taking the noun.

Instead of dropping a thing held by the player:
	say "You haven't digested [the noun] yet."

Instead of taking inventory:
	if the number of things enclosed by the player is 0, say "You have eaten nothing." instead;
	say "You have eaten ";
	list the contents of the player, tersely, giving brief inventory information, as a sentence, including contents;
	say "."
	
The description of the player is "As good-looking as ever: your coat is purest white, your mane thick and flowing, your hooves shiny and strong, and your horn long and fearsomely sharp."

Every turn:
	let r be the list of chromatic_foods held by the player;
	if the number of entries in r is seven and the beans are held by the player and a random chance of 1 in 3  succeeds:
		say "Your stomach rumbles fiercely.  It's time."

Volume 3 - Elysian Setting

Book One - Elysian Fields

Elysian Fields is a room.  "The Elysian Fields stretch endlessly in all (well, all horizontal) directions.  Green grass extends to the horizon, dotted here and there with specks of red and clumps of violet.  A grove of citrus stands nearby.  A row of colorful, stalky bushes outline a low ridge.  A creek meanders below the ridge, through a bit of farmland, with several kinds of shrubs planted in neat rows."

Elysian Fields is north, south, east, west, northeast, northwest, southeast, and southwest of Elysian Fields.

Instead of going down in Elysian Fields, say "You paw at the ground a little, but don't really succeed in digging much of a hole, much less a tunnel."

The sky is scenery in Elysian Fields.  "The sky above the fields is the clear, untroubled blue of television tuned to a dead channel.  White, fluffy clouds drift lazily by far overhead."  Understand "blue", "untroubled", "clear", "television", "channel", "white", "fluffy", "cumulus", "cloud", "clouds", "above", "far", and "dead" as the sky.  Does the player mean doing something to the sky: it is very unlikely.

Instead of going up in Elysian Fields:
	if anything is held by the player:
		instead try farting;
	otherwise:
		say "Can't do that...yet!"

Book Two - Food

Some crops are scenery_food in Elysian Fields.  The description of the crops is "There are three kinds of crop cultivated here: bush beans, blueberries, and, weirdly, [italic type]indigofera tinctoria[roman type] (that is, indigo)."  Understand "crop", "cultivation", "garden", "shrub", "shrubs", "farm", "farmland", "row", "rows", "neat", "shrub", "creek", and "stream" as the crops.  The actual_food of the crops is the beans.

After examining the crops:
	if the beans are not held by the player, now the beans are in the location;
	if the indigo is not held by the player, now the indigo is in the location;
	if the blueberries are not held by the player, now the blueberries are in the location.

Before taking the crops, instead say "You will need to be more specific."

Some scenery_beans are scenery_food in Elysian Fields.  The actual_food of scenery_beans is beans.  Instead of examining the scenery_beans, try examining the crops.  Understand "bush", "bushes", "bean", and "beans" as scenery_beans.

Some beans are things. Understand "bush", "bean", and "beans" as beans.  The description is "These are unremarkable-looking bush beans."  They are edible.  Report taking the beans: instead say "The beans are reasonably tasty, and they are certain to give you gas."  Instead of smelling the beans, say "The beans don't have much of a smell; you have to eat them for that."  The indefinite article is "some".

Some scenery_strawberries are scenery_food in Elysian Fields. The actual_food of scenery_strawberries is strawberries.
The printed name is "strawberries".  Understand "red", "speck", "specks", "berry", "berries", "strawberry", and "strawberries" as the scenery_strawberries.  The description of the scenery_strawberries is "On closer inspection, the red specks resolve into clumps of wild strawberries."  

Some strawberries are chromatic_food.  Understand "red", "wild", "strawberry", "berry", and "berries" as  strawberries.  The color of strawberries is "red". Report taking the strawberries: instead say "The strawberries are succulent and delicious."  Instead of smelling the strawberries, say "The strawberries smell tart and tantalizing."
	
Some scenery_citrus is scenery_food in Elysian Fields.  The actual_food of scenery_citrus is oranges.  The printed name is "orange trees".  Understand "orange", "tree", "oranges", "trees", "branch", "branches", "citrus", and "fruit" as scenery_citrus.  The description of the scenery_citrus is "These are orange trees, with ripe oranges hanging from the branches."   

Some oranges are chromatic_food.  Understand "ripe" and "juicy" as oranges.  The color of oranges is "orange".   The description is "Many ripe, juicy oranges hang from the tree."  Report taking oranges: instead say "The oranges are ripe and tangy."  Instead of smelling oranges, say "The orange peel smells enticing."

Scenery_forsythia is scenery_food in Elysian Fields.  The actual_food of scenery_forsythia is forsythia.  The printed name is "forsythia".  Understand "low", "ridge", "ridgleline", "stalk", "stalks", "long", "stalky", "bush", "bushes", "colorful", "yellow", "flower", "bloom", "blooms", "flowers", "small", "little", and "forsythia" as scenery_forsythia.  The description is "The bushes on the ridgeline turn out to be forsythia in bloom: long stalks covered in little yellow flowers."

Some forsythia is chromatic_food.  The description is "Little yellow flowers growing on a bush."  The color of the forsythia is "yellow".  Report taking forsythia: instead say "The forsythia makes you sneeze as you get close to it, but you eat it anyway.  It's kind of peppery."  Instead of smelling forsythia, say "Achoo!"

Scenery_grass is scenery_food in Elysian Fields.  The actual_food of scenery_grass is grass.  The printed name is "grass".  Understand "grass", "green", 
"delicious", "emerald-green", "beautiful", "beautifully", "manicured", "beautifully-manicured", "emerald", "lawn", "thick", "lush", and "luscious" as scenery_grass.  The description is "The grass stretches away in all directions like a beautifully-manicured lawn, luscious and emerald-green."

Some grass is chromatic_food.  The description is "The grass is thick and lush."  The color of grass is "green".  Report taking grass: instead say "The grass tastes every bit as good as it looks."  Instead of smelling grass, say "Your mouth waters as you smell the delicious grass."

Some scenery_blueberries are scenery_food in Elysian Fields.  Instead of examining the scenery_blueberries, try examining the crops.  The printed name is "blueberries".  The actual_food of the scenery_blueberries is blueberries.  Understand "blue", "berry", "berries", "blueberries", and "blueberry" as scenery_blueberries.

Some blueberries are chromatic_food.  The description is "Ripe blueberries grow on a number of bushes planted in neat rows." The color of blueberries is "blue".  Report taking blueberries: instead say "The blueberries burst in little pulses of sweetness as you gobble them from a bush."  Instead of smelling blueberries, say "The blueberries smell magnificent."

Some scenery_indigo is scenery_food in Elysian Fields.  Instead of examining the scenery_indigo, try examining the crops.  The printed name is "indigo".  The actual_food of the scenery_indigo is indigo.  Understand "indigo", "purple", "oval", "leaves", "flower", "flowers", "indigofera", "tinctoria", and "shrub" as scenery_indigo.  

Some indigo is chromatic_food.  The description is "[italic type]Indigofera tinctoria[roman type] is a shrub with oval leaves and purple flowers."  The color of indigo is "indigo".  Report taking the indigo: instead say "You gamely chew and swallow the indigo.  It tastes faintly medicinal."  Instead of smelling the indigo, say "The indigo really doesn't have much of an odor."

Scenery_violets is scenery_food in Elysian Fields.  The description is "The clumps of violet are, it turns out, small patches of violets."  Understand "violet", "violets", "flower", "flowers", "purple", "clump", "clumps", "perfumed", "perfume", "patches", "bright", "brightly", "brightly-colored", "sweet", "sweet-smelling", and "patch" as scenery_violets.  The actual_food of scenery_violets is violets.  The printed name is "violets".

Some violets are chromatic_food.  The description is "These are clumps of brightly-colored, sweet-smelling violets."  Report taking violets: instead say "The violets taste cloyingly sweet, kind of like perfume."  Instead of smelling violets, say "The violets smell just like perfume."  The color of violets is "violet".